Flash belleğimdeki dosyalar görünmüyor!
Flash belleğimdeki dosyalar görünmüyor!
[alert type=”info” close=”false”]Windows XP için güncelleme yapılmıştır. Windows XP kullanıcıları yazının sonuna göz atmayı ihmal etmesinler.[/alert]
Geçenlerde bilgisayarıma Mac kurmuştum. Flash bellek üzerinden yaptığım kurulumdan sonra 16 GBlık USB3.0 belleğimi tekrar düzelteyim dedim. Neyse belleği formatladım. Bu arada diğer belleklerimi de bir kontrol edeyim, içlerinde ne var ne yok derken, bir belleğimde virüs varmış. Kaspersky temizleme işlemini yaptıktan sonra bir baktım ki bizim bellekteki bütün klasörler gizli halde.
Flash bellek virüslerinin en kötü özelliği de bu aslında. Gerçek klasörü gizleyerek, kendi oluşturduğu sahte bir exe dosyası ile bütün sisteme bulaşıyor. Ben de normal dos komutlarınla bu işi çözeriz deyim, DOS ekranını açtım. Kullanacağım ATTRIB komutunun parametrelerini işim sağlam olsun diye bir internetten kontrol edeyim dedim. Bu esnada, “ulan ayda yılda bir başına geliyor, her seferinde parametre mi kontrol edeceksin” dedim kendi kendime. En iyisi bir BAT dosyası hazırlayarak, karşıma gelen her gizli dosyaya sahip flash belleklerde ben bunu kullanırım diye içimden geçirdim.
Oturdum bir bat dosyası yazmaya. Unutmadan söyleyeyim bat dosyasında A: B: ve C: sürücülerini tanımlamadım. Malum A ve B sürücüleri disket, C sürücüsü de genelde sistem sürücüsü olduğu için bu harflere flash bellek ataması yapılmıyor. Komutları aşağıda vereceğim, isteyen kontrol etsin. Hem açıklamalarınla yazdım. Bat dosyası oluşturmak isteyenlere de rehber olur, hem de akıllarda soru işareti kalmasın. Malum bat dosyası çalıştırılıyor. Dos komutlar ciddi komutlar en nihayetinde. Her neyse lafı fazla uzatmayayım. Kodlar ve bat dosyasının indirme linki aşağıda:
[syntax type=”dos”]
@ECHO off
:: RENGİ AYARLAYALIM – 0A YEŞİL =)
COLOR 0A
:: BAŞLIK VERELİM
TITLE GIZLI DOSYA ve KLASORLERI GOSTER
:: ANA BÖLÜME GİT
GOTO ANASAYFA
:: KULLANICIYA İLK GÖZÜKECEK BÖLÜMÜMÜZ
:ANASAYFA
CLS
ECHO.
ECHO.
ECHO ——— GIZLI DOSYA ve KLASORLERI GOSTER ———
ECHO.
ECHO.
ECHO * Bu program viruslerden dolayi dosya ve klasorleri gizlenmis
ECHO.
ECHO flash belleklerdeki gizlilik ozelliklerini kaldirir.
ECHO.
ECHO.
ECHO * Bu program Erdem ARSLAN tarafindan yazilmistir.
ECHO.
ECHO * http://www.erdemarslan.com/
ECHO.
ECHO * Soru ve sorunlariniz icin web sitemi kullanabilirsiniz.
ECHO.
ECHO.
:: DEVAM MI TAMAM MI?
CHOICE /C EH /N /M “Devam etmek istiyor musunuz? E- Evet H- Hayir”
IF ERRORLEVEL 2 GOTO END
IF ERRORLEVEL 1 GOTO GOSTER
:GOSTER
:: ÖNCEKİ SATIRLARI SİL
CLS
:: İŞLEMLERE DEVAM EDELİM
:: HANGİ SÜRÜCÜNÜN İÇERİĞİNDEKİ GİZLİ DOSYALAR GÖSTERİLECEK SORALIM
ECHO.
ECHO.
CHOICE /C DEFGHIJKLMNOPQRSTUVWXYZ /N /M “Lutfen flash bellek surucunuzun harfini giriniz”
:: GİRİLEN DEĞERE GÖRE SÜRÜCÜ HARFİNİ BUL
IF ERRORLEVEL 1 SET DRIVE=D:
IF ERRORLEVEL 2 SET DRIVE=E:
IF ERRORLEVEL 3 SET DRIVE=F:
IF ERRORLEVEL 4 SET DRIVE=G:
IF ERRORLEVEL 5 SET DRIVE=H:
IF ERRORLEVEL 6 SET DRIVE=I:
IF ERRORLEVEL 7 SET DRIVE=J:
IF ERRORLEVEL 8 SET DRIVE=K:
IF ERRORLEVEL 9 SET DRIVE=L:
IF ERRORLEVEL 10 SET DRIVE=M:
IF ERRORLEVEL 11 SET DRIVE=N:
IF ERRORLEVEL 12 SET DRIVE=O:
IF ERRORLEVEL 13 SET DRIVE=P:
IF ERRORLEVEL 14 SET DRIVE=Q:
IF ERRORLEVEL 15 SET DRIVE=R:
IF ERRORLEVEL 16 SET DRIVE=S:
IF ERRORLEVEL 17 SET DRIVE=T:
IF ERRORLEVEL 18 SET DRIVE=U:
IF ERRORLEVEL 19 SET DRIVE=V:
IF ERRORLEVEL 20 SET DRIVE=W:
IF ERRORLEVEL 21 SET DRIVE=X:
IF ERRORLEVEL 22 SET DRIVE=Y:
IF ERRORLEVEL 23 SET DRIVE=Z:
IF ERRORLEVEL 24 SET DRIVE=None
:: SÜRÜCÜ TANIMLANMAMIŞ İSE SÜRÜCÜ YOK DE
IF %DRIVE% EQU “None” GOTO SURUCUYOK
:: SÜRÜCÜ AKTİF Mİ BAKALIM BAKALIM. AKTIF DEGILSE SÜRÜCÜ YOK DE
IF NOT EXIST %DRIVE%\NUL GOTO SURUCUYOK
ECHO.
ECHO.
ECHO Temizlemek icin %DRIVE% surucusunu sectiniz
ECHO.
ECHO Sistem hazirlaniyor. Lutfen bekleyiniz.
ECHO.
ECHO Surucu hazirlaniyor…
ECHO.
ECHO Gizli klasor ve dosya ozellikleri kaldiriliyor.
ECHO.
ECHO Bu islem disk buyuklugunuze gore bir kac dakika surebilir.
ECHO.
ECHO Lutfen bekleyiniz…
ECHO.
ATTRIB -R -A -S -H %DRIVE%\*.* /S /D
GOTO ISLEMTAMAM
:: İŞLEM TAMAMLANDI NE YAPMAK İSTERSİN?
:ISLEMTAMAM
CLS
ECHO.
ECHO.
ECHO Islem basari ile tamamlandi.
ECHO.
CHOICE /C:ABC /N /M “Simdi ne yapmak istersin? A-Ana menu B-Baska surucu C-Cik”
IF ERRORLEVEL 3 GOTO END
IF ERRORLEVEL 2 GOTO GOSTER
IF ERRORLEVEL 1 GOTO ANASAYFA
:: SURUCU BULUNAMADI HATASI VER VE ÇIK
:SURUCUYOK
CLS
ECHO.
ECHO.
ECHO SECTIGINIZ SURUCU SISTEMINIZDE TANIMLI DEGIL. ISLEM IPTAL EDILDI.
ECHO.
ECHO.
CHOICE /C:EH /N /M “Baska bir surucu denemek ister misiniz? E – EVET H – HAYIR”
IF ERRORLEVEL 2 GOTO END
IF ERRORLEVEL 1 GOTO GOSTER
:: ÇIKIŞ
:END
EXIT
[/syntax]
Yazdığım BAT dosyasının en güzel tarafı, seçtiğiniz sürücü harfinde bir flash bellek yoksa, sistem uyarı veriyor. Aynı zamanda, bir bellek için yaptığınız işlem tamamlandıktan sonra, programdan çıkmadan başka bir belleği de temizleyebiliyorsunuz. İyi günlerde kullanmanız dileğimle.
[alert type=”error” close=”false”]Windows XP için güncelleme[/alert]
Yukarıda verdiğim bat dosyasını Windows 8.1 üzerinde hazırlamıştım. Ancak Windows XP üzerinde çalıştırmak istediğimde hata verdi. Nedeni ise “choice” komutunun Windows XP de kaldırılmış olduğunu öğrendim. Microsoft 95/98 sürümlerinde kullandığı choice.exe dosyasını sistem dosyalarından XP de kaldırmış ve Windows Vista ve üst sürümlerinde tekrar koymuş. Kısa bir araştırmadan sonra Microsoftun choice.exe yi sonradan tekrar yayınladığını gördüm. http://hp.vector.co.jp/authors/VA007219/dkclonesup/choice.html adresinden choice.exe yi tekrar bat dosyasına dahil ettim. Ancak bu sürümde choice.exe’nin komutları çok az da olsa, Windows 8.1 de bulunan sürümlerden farklı. Dolayısı kodları da tekrar düzenleyerek, Windows XP için yeni bir sürüm oluşturdum. İndirme linkini aşağıda görebilirsiniz.
Bol virüssüz günler…
[button url=”http://www.erdemarslan.com/yuklemeler/gizli_goster.rar” style=”success” size=”default” block=”false” target=”_blank”]Gizli Dosyaları Göster.BAT indir[/button] [button url=”http://www.erdemarslan.com/yuklemeler/gizli_goster_xp.rar” style=”danger” size=”default” block=”false” target=”_blank”]Gizli Dosyaları Göster.BAT Windows XP için indir[/button]
Böyle değerli bir paylaşımın yorumsuz bırakılması beni üzdü. Daha önceden buna benzer bir bat dosyam vardı bilgisayarımda bulamadım. Sizin yazdığınız program tam ilaç oldu teşekkürler.